Waldens inertial drive is an optical illusion

[FredWalter]

Please feel free to "do the math" and prove me wrong.

I've attached a simulation that I did using Maple.

Here is the Maple code:

---attempt01.txt
restart:
with(plots):
setoptions(scaling=constrained):

printf("For the mass track, use a 2-dimensional circle, centered at the origin (0, 0), with radius='RADIUS'.\n");
printf("Let the mass arm be rotating at 'RPM' rotations per minute.\n");
printf("Put the center of rotation of the mass arms at (0, OFFSET).\n");
printf("Put one end of the rotating arm at point P on the circle.\n");
printf("Let 'L'=the length from (0, OFFSET) to P.\n");
printf("Let 'A' be the angle between lines (0, 0) to (0, OFFSET), and (0, OFFSET) to P.\n\n");

printf("Using the Law of Cosines for the triangle formed by the above points, we get the following equation:\n");
printf("\tRADIUS*RADIUS = OFFSET*OFFSET+L*L-2*OFFSET*L*cos(A)\n");
EQN01 := RADIUS*RADIUS = OFFSET*OFFSET+L*L-2*OFFSET*L*cos(A):
ANS_EQN01 := solve(EQN01, L):
L := A -> OFFSET*cos(A) + sqrt(RADIUS*RADIUS+OFFSET*OFFSET*(cos(A)*cos(A)-1)):

printf("Solving '%a' for 'L' gives us:\n\tL(A)=%a\nand\n\tL(A)=%a\n\n", EQN01, ANS_EQN01[1], ANS_EQN01[2]);

printf("Let us use the first solution for L:\n\tL(%a)=%a\n\n", A, L(A));

Px_A := A -> L(A)*sin(A):
Py_A := A -> OFFSET-L(A)*cos(A):

printf("Using the relationship between the sides of our triangle, and angle A, we get the position of point P as a function of angle A:\n\tPx_A(A)=%a\n\tPy_A(A)=%a\n\n", Px_A(A), Py_A(A));

A := t -> t*(2*Pi)/RPM:
Px := t -> simplify(Px_A(A(t))):
Py := t -> simplify(Py_A(A(t))):
Vx := t -> simplify(diff(Px(t), t)):
Vy := t -> simplify(diff(Py(t), t)):
Ax := t -> simplify(diff(Vx(t), t)):
Ay := t -> simplify(diff(Vy(t), t)):
Sx := t -> simplify(diff(Ax(t), t)):
Sy := t -> simplify(diff(Ay(t), t)):

printf("Angle A is a function of time:\n\tA(t)=%a\n\n", A(t));

printf("Position of point P as a function of time:\n\tPx(t)=%a\n\tPy(t)=%a\n\n", Px(t), Py(t));
printf("Velocity vector at of point P as a function of time:\n\tVx(t)=%a\n\tVy(t)=%a\n\n", Vx(t), Vy(t));
printf("Acceleration vector at of point P as a function of time:\n\tAx(t)=%a\n\tAy(t)=%a\n\n", Ax(t), Ay(t));
printf("Surge vector at of point P as a function of time:\n\tSx(t)=%a\n\tSy(t)=%a\n\n", Sx(t), Sy(t));

RADIUS := 5: # 10" diameter mass track
OFFSET := RADIUS/2: # arbitrary
RPM := 1:
Alpha := 0: # do one full pass around the mass track
Omega := 1:
Curve := plot([Px(t), Py(t), t=Alpha..Omega], style=line, color=blue, thickness=2):

NumFrames := 30:
t := i -> Alpha + i*(Omega-Alpha)/NumFrames:
VScale := 0.1: # arbitrary
AScale := 0.01: # arbitrary
SScale := 0.001: # arbitrary

Points := display(seq(pointplot([Px(t(i)), Py(t(i))], style=point, symbol=circle, symbolsize=17, color=black), i=0..NumFrames), insequence=true):
VVectors := display(seq(arrow([Px(t(i)), Py(t(i))], VScale*<eval(Vx(a), a=t(i)), eval(Vy(a), a=t(i))>, width=.02, color=red), i=0..NumFrames), insequence=true):
AVectors := display(seq(arrow([Px(t(i)), Py(t(i))], AScale*<eval(Ax(a), a=t(i)), eval(Ay(a), a=t(i))>, width=.02, color=red), i=0..NumFrames), insequence=true):
SVectors := display(seq(arrow([Px(t(i)), Py(t(i))], SScale*<eval(Sx(a), a=t(i)), eval(Sy(a), a=t(i))>, width=.02, color=red), i=0..NumFrames), insequence=true):

printf("Here are some graphs following the point P for one full revolution of the mass arm, using the following values:\n\tRADIUS=%f\n\rOFFSET=%f\n\tRPM=%f\n\n", RADIUS, OFFSET, RPM);

display(Curve, Points, title="Mass Path");
display(Curve, VVectors, AVectors, title="Velocity+Acceleration");
display(Curve, AVectors, SVectors, title="Acceleration+Surge");

[CuriousChris]

Thats really cool.

I wonder if I can use that tool to test my own theory.

One thing though. As far as I can tell. and this may be just because I have never read a maple script before and may be relying too much on the images but are you modeling just one mass. Is that correct?

The image that shows the mass motion (mass_path.gif) only displays one and the vectors in the other gifs only show one. Waldens patent relies on multiples of two masses. its the summation of these forces I contend equals a vector force of 0.

CC

[FredWalter]

I wonder if I can use that tool to test my own theory.

If you can represent everything in your theory using equations then you probably can use Maple to help test your theory.

As far as I can tell. and this may be just because I have never read a maple script before and may be relying too much on the images but are you modeling just one mass. Is that correct?

Yes. I did this last year sometime, and haven't had time to extend it to cover two masses.

The image that shows the mass motion (mass_path.gif) only displays one and the vectors in the other gifs only show one. Waldens patent relies on multiples of two masses. its the summation of these forces I contend equals a vector force of 0.

You can integrate the force equation over the circle for one mass.

If F=M*V*V/R (as I've found in some text books) then you get a non-zero result.

If F=MA then you get 0.

When I look at the values of A and V as the mass moves over one revolution of the mass track, A=V*V/R only when V is tangential to the mass track (IE. for my setup, when x = 0).

It looks to me that F=MA is the general equation for force, and F=M*V*V/R is the equation that applies only when the velocity vector is tangential to the curve upon which the mass is moving.

I still haven't found a derivation of F=M*V*V/R, and until I find a derviation that shows it is always valid, I'm going to have to wonder if it valid to apply it to the WIP device.

Here is the maple code that I used to get these results (append it to the maple code in attempt01.txt):

---

Amagnitude := t -> sqrt(eval(Ax(a), a=t)^2+eval(Ay(a), a=t)^2):
Vmagnitude := t -> sqrt(eval(Vx(a), a=t)^2+eval(Vy(a), a=t)^2):
printf("\n");
for i from 0 by 0.05 to 1 do
printf("Time=%f Amagnitude=%f Vmagnitude^2/RADIUS=%f\n",
i, evalf(Amagnitude(i)), evalf(Vmagnitude(i)^2/RADIUS));
end do;
printf("\n");

FAx := t -> simplify(eval(MASS*Ax(a), a=t)):
FAy := t -> simplify(eval(MASS*Ay(a), a=t)):
FAmagnitude := t -> simplify(sqrt(eval(FAx(a), a=t)^2+eval(FAy(a), a=t)^2)):
Total_FAx := simplify(int(FAx(t), t=0..1)):
Total_FAy := simplify(int(FAy(t), t=0..1)):
Total_FAmagnitude := simplify(sqrt(Total_FAx^2+Total_FAy^2)):

FVx := t -> simplify(eval(MASS*Vx(a)^2/RADIUS, a=t)):
FVy := t -> simplify(eval(MASS*Vy(a)^2/RADIUS, a=t)):
FVmagnitude := t -> simplify(sqrt(eval(FVx(a), a=t)^2+eval(FVy(a), a=t)^2)):
Total_FVx := simplify(int(FVx(t), t=0..1)):
Total_FVy := simplify(int(FVy(t), t=0..1)):
Total_FVmagnitude := simplify(sqrt(Total_FVx^2+Total_FVy^2)):

printf("integrate F=MA over one revolution and you get: %a\n",
evalf(Total_FAmagnitude));
printf("integrate F=MV^2/R over one revolution and you get: %a\n",
evalf(Total_FVmagnitude));

---

Here is the output from the above Maple code:

---

Time=0.000000 Amagnitude=444.132198 Vmagnitude^2/RADIUS=444.132198
Time=0.050000 Amagnitude=433.781166 Vmagnitude^2/RADIUS=433.132245
Time=0.100000 Amagnitude=402.908288 Vmagnitude^2/RADIUS=399.815957
Time=0.150000 Amagnitude=353.424767 Vmagnitude^2/RADIUS=344.643860
Time=0.200000 Amagnitude=291.761146 Vmagnitude^2/RADIUS=272.820308
Time=0.250000 Amagnitude=227.928750 Vmagnitude^2/RADIUS=197.392088
Time=0.300000 Amagnitude=169.374817 Vmagnitude^2/RADIUS=134.142398
Time=0.350000 Amagnitude=119.976251 Vmagnitude^2/RADIUS=90.909984
Time=0.400000 Amagnitude=82.432846 Vmagnitude^2/RADIUS=65.672556
Time=0.450000 Amagnitude=58.162465 Vmagnitude^2/RADIUS=53.106629
Time=0.500000 Amagnitude=49.348022 Vmagnitude^2/RADIUS=49.348022
Time=0.550000 Amagnitude=58.162465 Vmagnitude^2/RADIUS=53.106628
Time=0.600000 Amagnitude=82.432846 Vmagnitude^2/RADIUS=65.672556
Time=0.650000 Amagnitude=119.976251 Vmagnitude^2/RADIUS=90.909985
Time=0.700000 Amagnitude=169.374817 Vmagnitude^2/RADIUS=134.142398
Time=0.750000 Amagnitude=227.928750 Vmagnitude^2/RADIUS=197.392088
Time=0.800000 Amagnitude=291.761146 Vmagnitude^2/RADIUS=272.820308
Time=0.850000 Amagnitude=353.424766 Vmagnitude^2/RADIUS=344.643860
Time=0.900000 Amagnitude=402.908288 Vmagnitude^2/RADIUS=399.815957
Time=0.950000 Amagnitude=433.781166 Vmagnitude^2/RADIUS=433.132245
Time=1.000000 Amagnitude=444.132198 Vmagnitude^2/RADIUS=444.132198

integrate F=MA over one revolution and you get: 0.
integrate F=MV^2/R over one revolution and you get: 158.5148465*csgn(MASS)*MASS