Pspice perpetual motion machine

[sandor]

I have a PMM that works in PSpice, the simulation files of which are up at

www.mininova.org/com/1381965

If you don't know, PSpice is software used to simulate electrical circuits.

Mucking around with the parameters I get as much as 627% efficiency. Isn't that funny? Someone told me to go to this forum because there was someone who was getting 'overunity' results with circuit sim software such as PSpice. I'd like it if someone with different, better software can simulate it for me because I have what I have and that's all I have and since it seems PSpice is hundreds of percent off, it must not be very good.

The 3 most interesting variants I have, from mucking around with the parameters are at the bottom. The last one shown was the 108% version where I first saw the anomaly. The middle one is the one where it's 627% but I don't like that one so much because the input current is a very large sinusoid that is very slightly offset (i.e. it draws little average power from a battery but it draws a lot of current and returns a lot of current, and it doesn't work when you connect the output back to the input even though its efficiency is the highest) and the first one shown fixes that problem, and yet still has 167% efficiency and that with accounting for series resistances with all the inductors (I actually made this circuit and these are the exact values of inductors and resistors - unfortunately generating the 200 kHz squarewave with nice sharp transitions with the right duty cycle proved to not be so easy, and I think the best transistor I have doesn't have NEARLY as low a saturation voltage as the generic transistor in the PSpice simulation, and then of course there are the nonlinear effects in the inductor magnetics such as hysteresis and saturation - but rest assured I wouldn't expect it to work anyway - I just built it because it was a coffin I'd rather see the nails driven into than leave it the least bit open)

On the last one you'll notice some comments left in that I guess no longer apply - like the turns ratio being 100-1 (I didn't intend it to be over 100% efficient, I had a much less lofty goal when I designed it, just to power a gas laser tube).

---------------------------------------------

PSpice perpetual motion machine
*167% efficiency with this one with input current remaining
*very positive (good power factor). 4.374 W in 7.346 W out
*Also 143 mW supplied to transistor base from V2 though
*Freedom on C2 - for instance 2.2U ok, in fact that increases efficiency.
*************************************
R1 1 2 13
L1 2 3 .00833 IC=.008332
C1 4 0 7.2n IC=139.7
L2 3 9 18U IC=.008332
R3 9 4 .13
Q1 3 6 0 QNL
D2 0 3 DMOD
V2 7 0 PULSE(0 3 0 .0125U .0125U 1.25U 5U)
R2 7 6 10
L3 10 0 6U IC=0
R4 8 10 .08
D3 8 1 DMOD
C2 1 0 1.9U IC=72.44
K1 L2 L3 .965
Rload 1 0 12500

.model QNL NPN(BF=100 VA=40 RB=1)
.model DMOD D(Is=1E-13)
.op
.tran 1E-8 2E-3
.probe
.end


PSpice perpetual motion machine
*627% efficiency with this one! 3.86W in 24.2 W out
*Also 390 mW supplied to transistor base from V2 though
*************************************
V1 1 0 DC 170
R1 1 2 5
L1 2 3 .015 IC=-.47322
C1 4 0 1U IC=311.27
L2 3 9 200U IC=-.47322
R3 9 4 .04
Q1 3 6 0 QNL
D2 0 3 DMOD
V2 7 0 PULSE(0 3 0 .5U .5U 50U 200U)
R2 7 6 3
L3 10 0 72U IC=0
R4 8 10 .015
D3 8 11 DMOD
C2 11 0 180U IC=170.5
K1 L2 L3 .965
Rload 11 0 1200

.model QNL NPN(BF=100 VA=40 RB=1)
.model DMOD D(Is=1E-13)
.op
.tran 1E-8 1E-1
.probe
.end


PSpice perpetual motion machine - note: Will not work in real life. Duh.
*Though I haven't actually tried, I think it's just a little more likely
*that PSPICE isn't perfectly accurate than that I have a Nobel Prize on
*the way for designing an honest to goodness functional PPM type 1.
*Note that 394 milliwatts are fed into the base of the transistor on
*average but that pales in comparison to the power dissipated by Rload.
*How did I discover this? I designed a soft switching power supply with
*PSpice and was terribly amused by its efficiency which it calculated at
*108%. So I thought I'd have some fun and use the output as the input, and
*then of course the 8% difference would be free energy used by Rload.
*About 15 watts. When it's running at 170 volts. Also note that I did not
*make Rload quite as low as it should be for equilibrium. The voltage
*starts at 170 and it ramps up to 200 volts in 200 milliseconds and the
*power dissipated in Rload has risen to 21 watts as well. I cheated a
*little, by picking this time length to imply that it is an exponential
*gain. If you simulate it for any longer you will see this trend stop, and
*it will actually start to go down, and then it will stabilize. I'm not
*really sure why. But when I simulated it for 2 seconds, it climbed to 200
*volts in .2 second, where it hit a sudden cusp, fell to 192 volts by .75
*second, and then suddenly stabilized and stayed solid there.
*Also I did this with Microsim Release 8. Perhaps my perpetual motion
*machine won't work in later releases if they're revised to become
*more accurate.
*************************************
R1 1 2 5
L1 2 3 .015 IC=.603776
C1 4 0 1U IC=356.626
L2 3 4 200U IC=.603776
*D1 3 5 DMOD
Q1 3 6 0 QNL
*Note. This is actually simulating a 2N6397 SCR
*Critical DV/DT 50 v/microsecond, rated 400 volts
*On both these aspects the SCR will be near its limit.
D2 0 3 DMOD
V2 7 0 PULSE(0 3 0 .5U .5U 50U 200U)
*note SCR ought to be triggered with pulses as brief as possible and
*the only important factor is the 200 microseconds. The pulses are a
*full 50 microseconds here because I'm simulating the SCR with a NPN
*transistor which needs the base current to continue. Make shorter than
*200 to increase output power, longer to decrease. Note. Make sure to
*get a SCR that doesn't self-trigger from the maximum possible rate of
*voltage rise when it isn't supposed to be triggered anyway.
R2 7 6 3
L3 8 0 100U IC=0
*Note. Turns ratio 100-1. If coupling coefficient higher, lower turns
*ratio to maybe 60 (.36 times the inductance) if k is .9 and not .75.
*That would mean L3 would be .72 instead of 2 henries.
D3 8 1 DMOD
C2 1 0 180U IC=169.66
K1 L2 L3 .9
Rload 1 0 1900

.model QNL NPN(BF=100 VA=40 RB=1)
.model DMOD D(Is=1E-13)
.op
.tran 1E-8 2E-1
.probe
.end

[therealrasta]

I found it interesting.. You should attempt a build?

[broli]

At least show a screenshot of the build. Not everyone is going to install some software just because some guy had something interesting. If 1000's of people came here and asked to do that... well you get my point.

Let me also add this. Why in the world would you put it on mininova. If you're not going to seed it at a pretty much daily basis then it's useless. But it on some free file hosting server.

[sandor]

Well I was thinking the text circuit descriptions were self explanatory but here's the thing.

Suppose you see the line:

R3 5 7 4k

that means a resistor which goes from nodes 5 to 7 with a resistance of 4 kilohms.

C1 2 5 4U IC=4

that would mean capacitor 1 is connected between nodes 2 and 5, has a value of 4 microfarads and an initial voltage it's charged to of 4 volts.

Q1 3 6 0 QNL

means a transistor whose collector is at node 3, base at node 6, and emitter at node 0, then if you look down to the model of QNL you see it's a NPN transistor.

I'm attaching some screen shots now.

[sandor]

If you look closely in fine print under each picture it shows the filenames which are descriptive of what you're seeing.

Also you apparently have to go to the bottom of all 4 pictures to see the scroll left and scroll right feature.

As you notice, the power factor of the one with 627% efficiency is terrible. It draws a lot of power and returns most of it. The one with a scant 167% efficiency, however, doesn't suffer that problem - but you can't see what its 'efficiency' is because in that circuit I don't have an input voltage source and an output load, I have the output connected back to the input and a load, and all you can see is the voltage ramping up.